Applications: Longitudinal oscillating chains; PDEs

[Analog_Engine.git] / scripts / TP1 10.30 Linear Molecule.LACE

# TP1 10.30 Linear Molecule
# In a linear molecule of symmetric construction of type A-B-A the atoms are harmonically coupled and are performing small oscillations around the equilibrium positions.

# s1'' = -omega0^2*s1 + omega0^2*s2
# s2'' = -my (-omega0^2*s1 + omega0^2*s2 + omega0^2*s2 - omega0^2*s3)
# s3'' = omega0^2*s2 - omega0^2*s3

# NB: all integrators have to run with 100 nF capacitance, i.e. SLOW mode

coefficient(1): omega0^2_1 # omega0^2 for s1
coefficient(2): omega0^2_2 # omega0^2 for s2 # same as omega0^2_1
coefficient(3): omega0^2_3 # omega0^2 for s3 # same as omega0^2_1
coefficient(4): my
coefficient(5): -1 -> -s1_0 # initial position of s1
coefficient(6): -1 -> -s3_0 # initial position of s3
# initial positon of s2, the central mass, is set to 0

iintegrate -omega0^2_1*s1, omega0^2_2*s2 -> -s1'   # input is s1''
iintegrate -s1' -> s1
   IC: -s1_0
invert s1 -> -s1
-s1 * omega0^2_1 -> -omega0^2_1*s1

iintegrate -my*bracket -> -s2'   # input is s2''
# the following integrator has to be built up manually as THAT only has 5 integrators and we need 6
# iintegrate -s2' -> s2
openamp -s2' -> s2
  loopback: capacitor(100nF)
s2 * omega0^2_2 -> omega0^2_2*s2
isum -omega0^2_1*s1, omega0^2_2*s2, omega0^2_2*s2, -omega0^2_3*s3 -> -bracket
-bracket * my -> -my*bracket

iintegrate omega0^2_2*s2, -omega0^2_3*s3 -> -s3'   # input is s3''
iintegrate -s3' -> s3
  IC: -s3_0
invert s3 -> -s3
-s3 * omega0^2_3 -> -omega0^2_3*s3

 output(x): s1
 output(y): s2
 output(z): s3